Import

Use the import block to import existing infrastructure resources into OpenTF, bringing them under OpenTF's management. Unlike the opentf import command, configuration-driven import using import blocks is predictable, works with CICD pipelines, and lets you preview an import operation before modifying state.

Once imported, OpenTF tracks the resource in your state file. You can then manage the imported resource like any other, updating its attributes and destroying it as part of a standard resource lifecycle.

The import block records that OpenTF imported the resource and did not create it. After importing, you can optionally remove import blocks from your configuration or leave them as a record of the resource's origin.

Syntax​

You can add an import block to any OpenTF configuration file. A common pattern is to create an imports.tf file, or to place each import block beside the resource block it imports into.

import {
  to = aws_instance.example
  id = "i-abcd1234"
}

resource "aws_instance" "example" {
  name = "hashi"
  # (other resource arguments...)
}

The above import block defines an import of the AWS instance with the ID "i-abcd1234" into the aws_instance.example resource in the root module.

The import block has the following arguments:

• to - The instance address this resource will have in your state file.
• id - A string with the import ID of the resource.
• provider (optional) - An optional custom resource provider, see The Resource provider Meta-Argument for details.

If you do not set the provider argument, OpenTF attempts to import from the default provider.

Import ID​

The import block requires you to provide the id argument with a literal string of your resource's import ID. OpenTF needs this import ID to locate the resource you want to import.

The identifier you use for a resource's import ID is resource-specific. You can find the required ID in the provider documentation for the resource you wish to import.

Plan and apply an import​

OpenTF processes the import block during the plan stage. Once a plan is approved, OpenTF imports the resource into its state during the subsequent apply stage.

To import a resource using import blocks, you must:

1. Define an import block for the resource(s).
2. Add a corresponding resource block to your configuration , or generate configuration for that resource.
3. Run opentf plan to review how OpenTF will import the resource(s).
4. Apply the configuration to import the resources and update your OpenTF state.

The import block is idempotent, meaning that applying an import action and running another plan will not generate another import action as long as that resource remains in your state.

OpenTF only needs to import a given resource once. Attempting to import a resource into the same address again is a harmless no-op. You can remove import blocks after completing the import or safely leave them in your configuration as a record of the resource's origin for future module maintainers. For more information on maintaining configurations over time, see Refactoring.

Resource configuration​

Before importing, you must add configuration for every resource you want OpenTF to import. Otherwise, OpenTF throws an error during planning, insisting you add resource configuration before it can successfully import. You can create resource configuration manually or generate it using OpenTF.

We recommend writing a resource block if you know what most of the resource's arguments will be. For example, your configuration may already contain a similar resource whose configuration you can copy and modify.

We recommend generating configuration when importing multiple resources or a single complex resource that you do not already have the configuration for.

Add a resource block​

Add a resource block for the resource to import. The resource address must match the import block's to argument.

import {
  to = aws_instance.example
  id = "i-abcd1234"
}

resource "aws_instance" "example" {
  name = "renderer"
}

Generate configuration​

OpenTF can generate HCL for resources that do not already exist in configuration. For more details, see Generating Configuration.

Examples​

The following example demonstrates how to import into a module.

import {
  to = module.instances.aws_instance.example
  id = "i-abcd1234"
}

The below example shows how to import a resource that includes count.

import {
  to = aws_instance.example[0]
  id = "i-abcd1234"
}

The below example shows how to import a resource that includes for_each.

import {
  to = aws_instance.example["foo"]
  id = "i-abcd1234"
}

Finally, the below example demonstrates how to import from a custom resource provider.

provider "aws" {
  alias = "europe"
  region = "eu-west-1"
}

import {
  provider = aws.europe
  to = aws_instance.example["foo"]
  id = "i-abcd1234"
}